include(${CMAKE_CURRENT_LIST_DIR}/cmake/rely.cmake)
set(Aethera_Kernel_dependencies aethera_kernel::taskflow global::magic_enum global::expected)
if (Aethera_BUILD_TESTS)
    set(Aethera_Kernel_test_targets)
    list(APPEND Aethera_Kernel_dependencies global::GTest)
endif ()
rcl_add_dependency_action_targets(Aethera_Kernel_env ${Aethera_Kernel_dependencies})
set_target_properties(Aethera_Kernel_env PROPERTIES FOLDER Aethera_Kernel)
library_get_missing_with_rely(Aethera_Kernel_dependencies_installed ${Aethera_Kernel_dependencies})
if (Aethera_Kernel_dependencies_installed)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Aethera_Kernel dependencies are not installed. Build Aethera_Kernel_env first")
    return()
endif ()
rcl_load_dependency_environment(${Aethera_Kernel_dependencies})
find_package(Threads REQUIRED)
find_package(Taskflow CONFIG REQUIRED)
find_package(magic_enum CONFIG REQUIRED)
find_package(tl-expected CONFIG REQUIRED)
if (Aethera_BUILD_TESTS)
    find_package(GTest CONFIG REQUIRED)
endif ()
set(Aethera_Kernel_source_dir "${CMAKE_CURRENT_LIST_DIR}/src/kernel")
append_glob_source(Aethera_Kernel_sources "${Aethera_Kernel_source_dir}")
add_library(Aethera_Kernel STATIC ${Aethera_Kernel_sources})
add_library(Renderive::Kernel ALIAS Aethera_Kernel)
set_target_properties(Aethera_Kernel PROPERTIES EXPORT_NAME Kernel)
target_include_directories(Aethera_Kernel PUBLIC
        "$<BUILD_INTERFACE:${Aethera_Kernel_source_dir}>"
        "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
)
target_compile_features(Aethera_Kernel PUBLIC cxx_std_20)
target_link_libraries(Aethera_Kernel PUBLIC
        Taskflow::Taskflow
        magic_enum::magic_enum
        tl::expected
)
target_link_libraries(Aethera_Kernel PRIVATE Threads::Threads)
function(Aethera_stage_kernel_runtime target)
    if (WIN32)
        add_custom_command(TARGET "${target}" POST_BUILD
                COMMAND "${CMAKE_COMMAND}" -E copy_if_different
                "$<TARGET_FILE:TBB::tbb>"
                "$<TARGET_FILE_DIR:${target}>"
                COMMENT "Staging oneTBB runtime for ${target}"
                VERBATIM)
    endif ()
endfunction()
if (MSVC)
    target_compile_options(Aethera_Kernel PRIVATE /utf-8)
endif ()
add_executable(Aethera_Kernel_exe "${CMAKE_CURRENT_LIST_DIR}/src/test/main.cpp")
target_link_libraries(Aethera_Kernel_exe PRIVATE Aethera_Kernel)
install(TARGETS Aethera_Kernel
        EXPORT RenderiveTargets
        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
install(DIRECTORY "${Aethera_Kernel_source_dir}/renderive"
        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
        FILES_MATCHING PATTERN "*.h" PATTERN "*.hpp" PATTERN "*.inl")
if (Aethera_BUILD_TESTS)
    set(Aethera_Kernel_test_dir "${CMAKE_CURRENT_LIST_DIR}/tests")
    append_glob_source(Aethera_Kernel_test_sources "${Aethera_Kernel_test_dir}")
    # Concrete 2D/3D scene tests belong to their owning modules.  The former
    # header-only Scene_Context fixtures were removed with the Builder-based
    # scene API, so Kernel's suite must remain independently linkable.
    list(FILTER Aethera_Kernel_test_sources EXCLUDE REGEX
            "(Real_Time_Data_Test|Renderable_Base_Test|Color_Cache_Test|Renderable_Test|Scene_Base_Test|Scene_Test|Dynamic_Renderable_Lifecycle_Test|Render_Plan_Execution_Test|Scene_Inheritance_Test|Scene_Memory_Resource_Test|Scene_State_Observer_Test|Scene2D_Context_Test|Scene2D_Render_Order_Test|Scene3D_Context_Test|Threading_Contract_Test)\\.cpp$")
    foreach (Aethera_Kernel_test_source IN LISTS Aethera_Kernel_test_sources)
        if (NOT Aethera_Kernel_test_source MATCHES "\\.(c|cc|cpp|cxx)$")
            continue()
        endif ()
        file(RELATIVE_PATH Aethera_Kernel_test_name "${Aethera_Kernel_test_dir}" "${Aethera_Kernel_test_source}")
        string(REGEX REPLACE "\\.[^.]+$" "" Aethera_Kernel_test_name "${Aethera_Kernel_test_name}")
        string(MAKE_C_IDENTIFIER "${Aethera_Kernel_test_name}" Aethera_Kernel_test_name)
        set(Aethera_Kernel_test_target "Aethera_Kernel_${Aethera_Kernel_test_name}")
        add_executable("${Aethera_Kernel_test_target}" "${Aethera_Kernel_test_source}")
        target_include_directories("${Aethera_Kernel_test_target}" PRIVATE
                "${Aethera_Kernel_test_dir}"
                "${CMAKE_CURRENT_LIST_DIR}/../render_2D"
                "${CMAKE_CURRENT_LIST_DIR}/../render_3D"
        )
        target_link_libraries("${Aethera_Kernel_test_target}" PRIVATE Aethera_Kernel GTest::gtest_main)
        Aethera_stage_kernel_runtime("${Aethera_Kernel_test_target}")
        add_test(NAME "${Aethera_Kernel_test_target}" COMMAND "${Aethera_Kernel_test_target}")
        set_tests_properties("${Aethera_Kernel_test_target}" PROPERTIES
                LABELS "Aethera_Kernel"
                ENVIRONMENT "Aethera_ERROR_MODE=exception")
        list(APPEND Aethera_Kernel_test_targets "${Aethera_Kernel_test_target}")
    endforeach ()
    add_custom_target(Aethera_Kernel_check
            COMMAND "${CMAKE_CTEST_COMMAND}" --test-dir "${CMAKE_BINARY_DIR}"
            -C "$<CONFIG>" -L "^Aethera_Kernel$" --output-on-failure
            DEPENDS ${Aethera_Kernel_test_targets}
            USES_TERMINAL)
endif ()