引入第三方库

2026-08-20 10:43:27 +08:00
parent 5e95b1a1ce
commit 3e8cb7b1a8
51 changed files with 15 additions and 4375 deletions
@@ -0,0 +1,71 @@
+set(Aethera_render_2D_dependencies global::blend2d)
+if (RENDERIVE_BUILD_TESTS)
+    set(Aethera_render_2D_test_targets)
+    list(APPEND Aethera_render_2D_dependencies global::GTest)
+endif ()
+rcl_add_dependency_action_targets(Aethera_render_2D_env ${Aethera_render_2D_dependencies})
+set_target_properties(Aethera_render_2D_env PROPERTIES FOLDER Aethera_render_2D)
+library_get_missing_with_rely(Aethera_render_2D_dependencies_missing ${Aethera_render_2D_dependencies})
+if (Aethera_render_2D_dependencies_missing)
+    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Aethera_render_2D dependencies\n${Aethera_render_2D_dependencies_missing}\n are not installed. Build Aethera_render_2D_env first")
+    return()
+endif ()
+rcl_load_dependency_environment(${Aethera_render_2D_dependencies})
+find_package(blend2d CONFIG REQUIRED)
+if (RENDERIVE_BUILD_TESTS)
+    find_package(GTest CONFIG REQUIRED)
+endif ()
+if (NOT TARGET Aethera_Kernel)
+    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Aethera_render_2D requires Aethera_Kernel")
+    return()
+endif ()
+set(Aethera_render_2D_source_dir "${CMAKE_CURRENT_LIST_DIR}/render_2D")
+append_glob_source(Aethera_render_2D_sources "${Aethera_render_2D_source_dir}")
+add_library(Aethera_render_2D STATIC ${Aethera_render_2D_sources})
+add_library(Aethera::Render2D ALIAS Aethera_render_2D)
+set_target_properties(Aethera_render_2D PROPERTIES EXPORT_NAME Render2D)
+target_include_directories(Aethera_render_2D PUBLIC
+        "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}>"
+        "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
+)
+target_compile_features(Aethera_render_2D PUBLIC cxx_std_20)
+target_link_libraries(Aethera_render_2D PUBLIC
+        Aethera_Kernel
+        blend2d::blend2d)
+if (MSVC)
+    target_compile_options(Aethera_render_2D PRIVATE /utf-8)
+endif ()
+install(TARGETS Aethera_render_2D
+        EXPORT AetheraTargets
+        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+        RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
+install(DIRECTORY "${Aethera_render_2D_source_dir}/"
+        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/render_2D"
+        FILES_MATCHING PATTERN "*.h" PATTERN "*.hpp")
+if (RENDERIVE_BUILD_TESTS)
+    set(Aethera_render_2D_test_dir "${CMAKE_CURRENT_LIST_DIR}/tests")
+    append_glob_source(Aethera_render_2D_test_sources "${Aethera_render_2D_test_dir}")
+    foreach (Aethera_render_2D_test_source IN LISTS Aethera_render_2D_test_sources)
+        if (NOT Aethera_render_2D_test_source MATCHES "\\.(c|cc|cpp|cxx)$")
+            continue()
+        endif ()
+        file(RELATIVE_PATH Aethera_render_2D_test_name "${Aethera_render_2D_test_dir}" "${Aethera_render_2D_test_source}")
+        string(REGEX REPLACE "\\.[^.]+$" "" Aethera_render_2D_test_name "${Aethera_render_2D_test_name}")
+        string(MAKE_C_IDENTIFIER "${Aethera_render_2D_test_name}" Aethera_render_2D_test_name)
+        set(Aethera_render_2D_test_target "Aethera_render_2D_${Aethera_render_2D_test_name}")
+        add_executable("${Aethera_render_2D_test_target}" "${Aethera_render_2D_test_source}")
+        target_link_libraries("${Aethera_render_2D_test_target}" PRIVATE Aethera_render_2D GTest::gtest_main)
+        renderive_stage_kernel_runtime("${Aethera_render_2D_test_target}")
+        add_test(NAME "${Aethera_render_2D_test_target}" COMMAND "${Aethera_render_2D_test_target}")
+        set_tests_properties("${Aethera_render_2D_test_target}" PROPERTIES
+                LABELS "Aethera_render_2D"
+                ENVIRONMENT "RENDERIVE_ERROR_MODE=exception")
+        list(APPEND Aethera_render_2D_test_targets "${Aethera_render_2D_test_target}")
+    endforeach ()
+    add_custom_target(Aethera_render_2D_check
+            COMMAND "${CMAKE_CTEST_COMMAND}" --test-dir "${CMAKE_BINARY_DIR}"
+            -C "$<CONFIG>" -L "^Aethera_render_2D$" --output-on-failure
+            DEPENDS ${Aethera_render_2D_test_targets}
+            USES_TERMINAL)
+endif ()