171 lines
8.1 KiB
CMake
171 lines
8.1 KiB
CMake
# 加载 datoviz的依赖库
|
|
include(${CMAKE_CURRENT_LIST_DIR}/cmake/export.cmake)
|
|
set(Renderive_render_3D_dependencies
|
|
render_3D::cglm
|
|
render_3D::Vulkan-Hpp
|
|
render_3D::VulkanMemoryAllocator
|
|
render_3D::msdfgen
|
|
render_3D::msdf-atlas-gen
|
|
render_3D::tinyobjloader
|
|
render_3D::volk
|
|
render_3D::freetype
|
|
render_3D::tinyxml2
|
|
global::zlib
|
|
)
|
|
if (WIN32)
|
|
list(APPEND Renderive_render_3D_dependencies render_3D::PThreads4W)
|
|
endif ()
|
|
if (RENDERIVE_BUILD_TESTS)
|
|
list(APPEND Renderive_render_3D_dependencies global::GTest)
|
|
endif ()
|
|
rcl_add_dependency_action_targets(Renderive_render_3D_env ${Renderive_render_3D_dependencies})
|
|
set_target_properties(Renderive_render_3D_env PROPERTIES FOLDER Renderive_render_3D)
|
|
library_get_missing_with_rely(Renderive_render_3D_missing ${Renderive_render_3D_dependencies})
|
|
if (Renderive_render_3D_missing)
|
|
rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_render_3D dependencies\n${Renderive_render_3D_missing}\n are not installed. Build Renderive_render_3D_env first")
|
|
return()
|
|
endif ()
|
|
rcl_load_dependency_environment(${Renderive_render_3D_dependencies})
|
|
find_package(Vulkan REQUIRED)
|
|
find_package(Threads REQUIRED)
|
|
if (WIN32)
|
|
find_package(PThreads4W QUIET)
|
|
if (NOT PThreads4W_FOUND)
|
|
rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_render_3D PThreads4W installation is incomplete. Rebuild render_3D::PThreads4W")
|
|
return()
|
|
endif ()
|
|
endif ()
|
|
find_package(cglm CONFIG REQUIRED)
|
|
find_package(volk CONFIG REQUIRED)
|
|
find_package(VulkanMemoryAllocator CONFIG REQUIRED)
|
|
find_package(Freetype REQUIRED)
|
|
find_package(msdfgen CONFIG REQUIRED)
|
|
find_package(msdf-atlas-gen CONFIG REQUIRED)
|
|
find_package(tinyxml2 CONFIG REQUIRED)
|
|
find_package(tinyobjloader CONFIG REQUIRED)
|
|
find_package(ZLIB REQUIRED)
|
|
message(STATUS "${B}Vulkan_VERSION=${Vulkan_VERSION}${E}")
|
|
|
|
# Datoviz loads shaderc lazily when the first GLSL frame plan is executed. A process can
|
|
# therefore start successfully and fail only on its first 3D frame when the Vulkan SDK's Bin
|
|
# directory was not inherited by the launcher (for example, a fresh CLion run configuration).
|
|
# Record that runtime dependency once and stage it beside every executable that embeds render_3D.
|
|
if (WIN32)
|
|
get_filename_component(Renderive_render_3D_vulkan_bin
|
|
"${Vulkan_GLSLC_EXECUTABLE}" DIRECTORY)
|
|
find_file(Renderive_render_3D_shaderc_runtime
|
|
NAMES shaderc_shared.dll
|
|
HINTS
|
|
"${Renderive_render_3D_vulkan_bin}"
|
|
"$ENV{VULKAN_SDK}/Bin"
|
|
NO_DEFAULT_PATH
|
|
)
|
|
if (NOT Renderive_render_3D_shaderc_runtime)
|
|
message(FATAL_ERROR
|
|
"render_3D requires shaderc_shared.dll beside the Vulkan SDK tools")
|
|
endif ()
|
|
set_property(GLOBAL PROPERTY RENDERIVE_RENDER_3D_RUNTIME_FILES
|
|
"${Renderive_render_3D_shaderc_runtime}")
|
|
endif ()
|
|
|
|
function(renderive_stage_render_3D_runtime target)
|
|
if (NOT TARGET "${target}")
|
|
message(FATAL_ERROR "Cannot stage render_3D runtime for missing target: ${target}")
|
|
endif ()
|
|
renderive_stage_kernel_runtime("${target}")
|
|
if (WIN32)
|
|
get_property(Renderive_render_3D_runtime_files GLOBAL PROPERTY
|
|
RENDERIVE_RENDER_3D_RUNTIME_FILES)
|
|
add_custom_command(TARGET "${target}" POST_BUILD
|
|
COMMAND "${CMAKE_COMMAND}" -E copy_if_different
|
|
${Renderive_render_3D_runtime_files}
|
|
"$<TARGET_FILE_DIR:${target}>"
|
|
COMMENT "Staging Datoviz runtime dependencies for ${target}"
|
|
VERBATIM)
|
|
endif ()
|
|
endfunction()
|
|
|
|
if (RENDERIVE_BUILD_TESTS)
|
|
set(Renderive_render_3D_test_targets)
|
|
find_package(GTest CONFIG REQUIRED)
|
|
endif ()
|
|
if (NOT TARGET Renderive_Kernel)
|
|
rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_render_3D requires Renderive_Kernel")
|
|
return()
|
|
endif ()
|
|
add_subdirectory("${CMAKE_CURRENT_LIST_DIR}/datoviz" "${CMAKE_CURRENT_BINARY_DIR}/datoviz")
|
|
set(Renderive_render_3D_source_dir "${CMAKE_CURRENT_LIST_DIR}/render_3D")
|
|
append_glob_source(Renderive_render_3D_sources "${Renderive_render_3D_source_dir}")
|
|
add_library(Renderive_render_3D STATIC ${Renderive_render_3D_sources})
|
|
add_library(Renderive::Render3D ALIAS Renderive_render_3D)
|
|
set_target_properties(Renderive_render_3D PROPERTIES EXPORT_NAME Render3D)
|
|
target_include_directories(Renderive_render_3D PUBLIC
|
|
"$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}>"
|
|
"$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
|
|
)
|
|
target_compile_features(Renderive_render_3D PUBLIC cxx_std_20)
|
|
target_link_libraries(Renderive_render_3D PUBLIC Renderive_Kernel)
|
|
foreach (Renderive_render_3D_datoviz_target IN LISTS Renderive_render_3D_datoviz_targets)
|
|
target_link_libraries(Renderive_render_3D PRIVATE
|
|
"$<BUILD_INTERFACE:${Renderive_render_3D_datoviz_target}>")
|
|
endforeach ()
|
|
target_link_libraries(Renderive_render_3D PRIVATE
|
|
tinyobjloader::tinyobjloader
|
|
Threads::Threads
|
|
cglm::cglm
|
|
volk::volk
|
|
GPUOpen::VulkanMemoryAllocator
|
|
Vulkan::Vulkan
|
|
Freetype::Freetype
|
|
msdfgen::msdfgen
|
|
msdf-atlas-gen::msdf-atlas-gen
|
|
tinyxml2::tinyxml2
|
|
ZLIB::ZLIB
|
|
)
|
|
if (WIN32)
|
|
target_link_libraries(Renderive_render_3D PRIVATE PThreads4W::PThreads4W)
|
|
endif ()
|
|
if (MSVC)
|
|
# Datoviz is embedded from OBJECT libraries in this static archive. Its Windows headers
|
|
# otherwise declare every symbol as dllimport for this C++ translation unit.
|
|
target_compile_definitions(Renderive_render_3D PRIVATE DVZ_SHARED)
|
|
target_compile_options(Renderive_render_3D PRIVATE /utf-8)
|
|
endif ()
|
|
install(TARGETS Renderive_render_3D
|
|
EXPORT RenderiveTargets
|
|
ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
|
|
LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
|
|
RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
|
|
install(DIRECTORY "${Renderive_render_3D_source_dir}/"
|
|
DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/render_3D"
|
|
FILES_MATCHING PATTERN "*.h" PATTERN "*.hpp")
|
|
if (RENDERIVE_BUILD_TESTS)
|
|
set(Renderive_render_3D_test_dir "${CMAKE_CURRENT_LIST_DIR}/tests")
|
|
append_glob_source(Renderive_render_3D_test_sources "${Renderive_render_3D_test_dir}")
|
|
foreach (Renderive_render_3D_test_source IN LISTS Renderive_render_3D_test_sources)
|
|
if (NOT Renderive_render_3D_test_source MATCHES "\\.(c|cc|cpp|cxx)$")
|
|
continue()
|
|
endif ()
|
|
file(RELATIVE_PATH Renderive_render_3D_test_name "${Renderive_render_3D_test_dir}" "${Renderive_render_3D_test_source}")
|
|
string(MD5 Renderive_render_3D_test_hash "${Renderive_render_3D_test_name}")
|
|
string(SUBSTRING "${Renderive_render_3D_test_hash}" 0 8 Renderive_render_3D_test_hash)
|
|
get_filename_component(Renderive_render_3D_test_name "${Renderive_render_3D_test_source}" NAME_WE)
|
|
string(MAKE_C_IDENTIFIER "${Renderive_render_3D_test_name}" Renderive_render_3D_test_name)
|
|
set(Renderive_render_3D_test_target "Renderive_render_3D_${Renderive_render_3D_test_name}_${Renderive_render_3D_test_hash}")
|
|
add_executable("${Renderive_render_3D_test_target}" "${Renderive_render_3D_test_source}")
|
|
target_link_libraries("${Renderive_render_3D_test_target}" PRIVATE Renderive_render_3D GTest::gtest_main)
|
|
if (Renderive_render_3D_test_name STREQUAL "Gpu_Completion_Service_Tests")
|
|
target_link_libraries("${Renderive_render_3D_test_target}" PRIVATE volk::volk_headers)
|
|
endif ()
|
|
renderive_stage_render_3D_runtime("${Renderive_render_3D_test_target}")
|
|
add_test(NAME "${Renderive_render_3D_test_target}" COMMAND "${Renderive_render_3D_test_target}")
|
|
set_tests_properties("${Renderive_render_3D_test_target}" PROPERTIES LABELS "Renderive_render_3D")
|
|
list(APPEND Renderive_render_3D_test_targets "${Renderive_render_3D_test_target}")
|
|
endforeach ()
|
|
add_custom_target(Renderive_render_3D_check
|
|
COMMAND "${CMAKE_CTEST_COMMAND}" --test-dir "${CMAKE_BINARY_DIR}"
|
|
-C "$<CONFIG>" -L "^Renderive_render_3D$" --output-on-failure
|
|
DEPENDS ${Renderive_render_3D_test_targets}
|
|
USES_TERMINAL)
|
|
endif ()
|