44 lines
1.3 KiB
CMake
44 lines
1.3 KiB
CMake
@PACKAGE_INIT@
|
|
|
|
include(CMakeFindDependencyMacro)
|
|
|
|
find_dependency(Threads)
|
|
find_dependency(TBB CONFIG)
|
|
|
|
set(Renderive_Kernel_FOUND TRUE)
|
|
set(Renderive_Render2D_FOUND @RENDERIVE_INSTALL_2D@)
|
|
set(Renderive_Render3D_FOUND @RENDERIVE_INSTALL_3D@)
|
|
set(Renderive_Qt_FOUND @RENDERIVE_INSTALL_QT@)
|
|
|
|
if (@RENDERIVE_INSTALL_2D@)
|
|
find_dependency(blend2d CONFIG)
|
|
find_dependency(tl-expected CONFIG)
|
|
endif ()
|
|
|
|
if (@RENDERIVE_INSTALL_3D@)
|
|
find_dependency(Vulkan)
|
|
find_dependency(cglm CONFIG)
|
|
find_dependency(volk CONFIG)
|
|
find_dependency(VulkanMemoryAllocator CONFIG)
|
|
find_dependency(Freetype)
|
|
find_dependency(msdfgen CONFIG)
|
|
find_dependency(msdf-atlas-gen CONFIG)
|
|
find_dependency(tinyxml2 CONFIG)
|
|
find_dependency(tinyobjloader CONFIG)
|
|
find_dependency(ZLIB)
|
|
if (WIN32)
|
|
set(_Renderive_saved_module_path "${CMAKE_MODULE_PATH}")
|
|
list(PREPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/modules")
|
|
find_dependency(PThreads4W)
|
|
set(CMAKE_MODULE_PATH "${_Renderive_saved_module_path}")
|
|
unset(_Renderive_saved_module_path)
|
|
endif ()
|
|
endif ()
|
|
|
|
if (@RENDERIVE_INSTALL_QT@)
|
|
find_dependency(Qt5 CONFIG COMPONENTS Core Gui Widgets)
|
|
endif ()
|
|
|
|
include("${CMAKE_CURRENT_LIST_DIR}/RenderiveTargets.cmake")
|
|
check_required_components(Renderive)
|