if (POLICY CMP0144)
    cmake_policy(SET CMP0144 NEW)
endif ()
include("${CMAKE_CURRENT_LIST_DIR}/cmake/export.cmake")
set(Renderive_render_3D_dependencies render_3D::datoviz)
if (WIN32 AND NOT MINGW)
    list(APPEND Renderive_render_3D_dependencies render_3D::PThreads4W)
endif ()
if (RENDERIVE_BUILD_TESTS)
    list(APPEND Renderive_render_3D_dependencies global::GTest)
endif ()
rcl_add_dependency_action_targets(Renderive_render_3D_env ${Renderive_render_3D_dependencies})
set_target_properties(Renderive_render_3D_env PROPERTIES FOLDER Renderive_render_3D)
library_get_missing_with_rely(Renderive_render_3D_dependencies_missing ${Renderive_render_3D_dependencies})
if (Renderive_render_3D_dependencies_missing)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_render_3D dependencies\n${Renderive_render_3D_dependencies_missing}\n are not installed. Build Renderive_render_3D_env first")
    return()
endif ()
rcl_load_dependency_environment(${Renderive_render_3D_dependencies})
find_package(Vulkan REQUIRED)
if (WIN32 AND NOT MINGW)
    rcl_get_effective_install_dir(render_3D::PThreads4W PTHREADS4W_ROOT)
    find_package(PThreads4W CONFIG REQUIRED
            PATHS "${CMAKE_CURRENT_LIST_DIR}/cmake/package/PThreads4W"
            NO_DEFAULT_PATH
    )
endif ()
find_package(datoviz CONFIG REQUIRED)
if (RENDERIVE_BUILD_TESTS)
    find_package(GTest CONFIG REQUIRED)
endif ()
if (NOT TARGET Renderive_Kernel)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_render_3D requires Renderive_Kernel")
    return()
endif ()
set(Renderive_render_3D_source_dir "${CMAKE_CURRENT_LIST_DIR}")
append_glob_source(Renderive_render_3D_sources "${Renderive_render_3D_source_dir}")
list(FILTER Renderive_render_3D_sources EXCLUDE REGEX "/tests/")
add_library(Renderive_render_3D STATIC ${Renderive_render_3D_sources})
target_include_directories(Renderive_render_3D PUBLIC
        "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}>"
)
target_compile_features(Renderive_render_3D PUBLIC cxx_std_20)
target_link_libraries(Renderive_render_3D
        PRIVATE Renderive_Kernel datoviz::datoviz Vulkan::Vulkan
)
if (WIN32 AND NOT MINGW)
    target_link_libraries(Renderive_render_3D PRIVATE PThreads4W::PThreads4W)
endif ()
if (MSVC)
    target_compile_options(Renderive_render_3D PRIVATE /utf-8)
endif ()
if (RENDERIVE_BUILD_TESTS)
    set(Renderive_render_3D_test_dir "${CMAKE_CURRENT_LIST_DIR}/tests")
    append_glob_source(Renderive_render_3D_test_sources "${Renderive_render_3D_test_dir}")
    foreach (Renderive_render_3D_test_source IN LISTS Renderive_render_3D_test_sources)
        if (NOT Renderive_render_3D_test_source MATCHES "\\.(c|cc|cpp|cxx)$")
            continue()
        endif ()
        file(RELATIVE_PATH Renderive_render_3D_test_name "${Renderive_render_3D_test_dir}" "${Renderive_render_3D_test_source}")
        string(MD5 Renderive_render_3D_test_hash "${Renderive_render_3D_test_name}")
        string(SUBSTRING "${Renderive_render_3D_test_hash}" 0 8 Renderive_render_3D_test_hash)
        get_filename_component(Renderive_render_3D_test_name "${Renderive_render_3D_test_source}" NAME_WE)
        string(MAKE_C_IDENTIFIER "${Renderive_render_3D_test_name}" Renderive_render_3D_test_name)
        set(Renderive_render_3D_test_target "Renderive_render_3D_${Renderive_render_3D_test_name}_${Renderive_render_3D_test_hash}")
        add_executable("${Renderive_render_3D_test_target}" "${Renderive_render_3D_test_source}")
        target_link_libraries("${Renderive_render_3D_test_target}" PRIVATE
                Renderive_render_3D Renderive_Kernel datoviz::datoviz GTest::gtest_main
        )
        add_test(NAME "${Renderive_render_3D_test_target}" COMMAND "${Renderive_render_3D_test_target}")
        set_property(TEST "${Renderive_render_3D_test_target}" PROPERTY TIMEOUT 60)
        if (WIN32)
            set_property(TEST "${Renderive_render_3D_test_target}" PROPERTY ENVIRONMENT_MODIFICATION
                    "PATH=path_list_prepend:${DATOVIZ_ROOT}/bin"
                    "PATH=path_list_prepend:${PThreads4W_RUNTIME_DIR}"
            )
        endif ()
    endforeach ()
endif ()