set(Renderive_Qt_dependencies)
if (RENDERIVE_BUILD_TESTS)
    set(Renderive_Qt_test_targets)
    list(APPEND Renderive_Qt_dependencies global::GTest)
endif ()
rcl_add_dependency_action_targets(Renderive_Qt_env ${Renderive_Qt_dependencies})
set_target_properties(Renderive_Qt_env PROPERTIES FOLDER Renderive_Qt)
library_get_missing_with_rely(Renderive_Qt_dependencies_missing ${Renderive_Qt_dependencies})
if (Renderive_Qt_dependencies_missing)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_Qt dependencies\n${Renderive_Qt_dependencies_missing}\n are not installed. Build Renderive_Qt_env first")
    return()
endif ()
if (Renderive_Qt_dependencies)
    rcl_load_dependency_environment(${Renderive_Qt_dependencies})
endif ()
find_package(Qt5 CONFIG REQUIRED COMPONENTS Core Gui Widgets)
if (RENDERIVE_BUILD_TESTS)
    find_package(GTest CONFIG REQUIRED)
endif ()
if (NOT TARGET Renderive_render_2D)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_Qt requires Renderive_render_2D")
    return()
endif ()
set(Renderive_Qt_source_dirs
        "${CMAKE_CURRENT_LIST_DIR}/bridge"
        "${CMAKE_CURRENT_LIST_DIR}/plot"
)
set(Renderive_Qt_sources)
foreach (Renderive_Qt_source_dir IN LISTS Renderive_Qt_source_dirs)
    append_glob_source(Renderive_Qt_sources "${Renderive_Qt_source_dir}")
endforeach ()
add_library(Renderive_Qt STATIC ${Renderive_Qt_sources})
add_library(Renderive::Qt ALIAS Renderive_Qt)
set_target_properties(Renderive_Qt PROPERTIES AUTOMOC ON EXPORT_NAME Qt)
target_include_directories(Renderive_Qt PUBLIC
        "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/..>"
        "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
)
target_compile_features(Renderive_Qt PUBLIC cxx_std_20)
target_link_libraries(Renderive_Qt PUBLIC
        Renderive_render_2D
        Qt5::Core
        Qt5::Gui
        Qt5::Widgets
)
if (MSVC)
    target_compile_options(Renderive_Qt PRIVATE /utf-8)
endif ()
install(TARGETS Renderive_Qt
        EXPORT RenderiveTargets
        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
install(DIRECTORY "${CMAKE_CURRENT_LIST_DIR}/bridge/"
        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/Qt/bridge"
        FILES_MATCHING PATTERN "*.h" PATTERN "*.hpp")
install(DIRECTORY "${CMAKE_CURRENT_LIST_DIR}/plot/"
        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/Qt/plot"
        FILES_MATCHING PATTERN "*.h" PATTERN "*.hpp")
if (RENDERIVE_BUILD_TESTS)
    get_filename_component(Renderive_Qt_runtime_root "${Qt5_DIR}/../../.." ABSOLUTE)
    set(Renderive_Qt_test_dir "${CMAKE_CURRENT_LIST_DIR}/tests")
    append_glob_source(Renderive_Qt_test_sources "${Renderive_Qt_test_dir}")
    foreach (Renderive_Qt_test_source IN LISTS Renderive_Qt_test_sources)
        if (NOT Renderive_Qt_test_source MATCHES "\\.(c|cc|cpp|cxx)$")
            continue()
        endif ()
        file(RELATIVE_PATH Renderive_Qt_test_name "${Renderive_Qt_test_dir}" "${Renderive_Qt_test_source}")
        string(REGEX REPLACE "\\.[^.]+$" "" Renderive_Qt_test_name "${Renderive_Qt_test_name}")
        string(MAKE_C_IDENTIFIER "${Renderive_Qt_test_name}" Renderive_Qt_test_name)
        set(Renderive_Qt_test_target "Renderive_Qt_${Renderive_Qt_test_name}")
        add_executable("${Renderive_Qt_test_target}" "${Renderive_Qt_test_source}")
        target_link_libraries("${Renderive_Qt_test_target}" PRIVATE Renderive_Qt GTest::gtest)
        renderive_stage_kernel_runtime("${Renderive_Qt_test_target}")
        add_test(NAME "${Renderive_Qt_test_target}"
                COMMAND "${CMAKE_COMMAND}" -E env
                "PATH=${Renderive_Qt_runtime_root}/bin\;$ENV{PATH}"
                "QT_QPA_PLATFORM=offscreen"
                "QT_QPA_PLATFORM_PLUGIN_PATH=${Renderive_Qt_runtime_root}/plugins/platforms"
                "$<TARGET_FILE:${Renderive_Qt_test_target}>"
        )
        set_tests_properties("${Renderive_Qt_test_target}" PROPERTIES LABELS "Renderive_Qt")
        list(APPEND Renderive_Qt_test_targets "${Renderive_Qt_test_target}")
    endforeach ()
    add_custom_target(Renderive_Qt_check
            COMMAND "${CMAKE_CTEST_COMMAND}" --test-dir "${CMAKE_BINARY_DIR}"
                    -C "$<CONFIG>" -L "^Renderive_Qt$" --output-on-failure
            DEPENDS ${Renderive_Qt_test_targets}
            USES_TERMINAL)
endif ()