include(${CMAKE_CURRENT_LIST_DIR}/cmake/rely.cmake)
set(Renderive_Kernel_dependencies render_kernel::oneTBB)
if (RENDERIVE_BUILD_TESTS)
    set(Renderive_Kernel_test_targets)
    list(APPEND Renderive_Kernel_dependencies global::GTest)
endif ()
rcl_add_dependency_action_targets(Renderive_Kernel_env ${Renderive_Kernel_dependencies})
set_target_properties(Renderive_Kernel_env PROPERTIES FOLDER Renderive_Kernel)
library_get_missing_with_rely(Renderive_Kernel_dependencies_installed ${Renderive_Kernel_dependencies})
if (Renderive_Kernel_dependencies_installed)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_Kernel dependencies are not installed. Build Renderive_Kernel_env first")
    return()
endif ()
rcl_load_dependency_environment(${Renderive_Kernel_dependencies})
find_package(Threads REQUIRED)
find_package(TBB CONFIG REQUIRED)
if (RENDERIVE_BUILD_TESTS)
    find_package(GTest CONFIG REQUIRED)
endif ()
set(Renderive_Kernel_source_dir "${CMAKE_CURRENT_LIST_DIR}/src")
append_glob_source(Renderive_Kernel_sources "${Renderive_Kernel_source_dir}")
add_library(Renderive_Kernel STATIC ${Renderive_Kernel_sources})
add_library(Renderive::Kernel ALIAS Renderive_Kernel)
set_target_properties(Renderive_Kernel PROPERTIES EXPORT_NAME Kernel)
target_include_directories(Renderive_Kernel PUBLIC
        "$<BUILD_INTERFACE:${Renderive_Kernel_source_dir}>"
        "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
)
target_compile_features(Renderive_Kernel PUBLIC cxx_std_20)
target_link_libraries(Renderive_Kernel PUBLIC TBB::tbb)
target_link_libraries(Renderive_Kernel PRIVATE Threads::Threads)
function(renderive_stage_kernel_runtime target)
    if (WIN32)
        add_custom_command(TARGET "${target}" POST_BUILD
                COMMAND "${CMAKE_COMMAND}" -E copy_if_different
                "$<TARGET_FILE:TBB::tbb>"
                "$<TARGET_FILE_DIR:${target}>"
                COMMENT "Staging oneTBB runtime for ${target}"
                VERBATIM)
    endif ()
endfunction()
if (MSVC)
    target_compile_options(Renderive_Kernel PRIVATE /utf-8)
endif ()
install(TARGETS Renderive_Kernel
        EXPORT RenderiveTargets
        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
install(DIRECTORY "${Renderive_Kernel_source_dir}/renderive"
        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
        FILES_MATCHING PATTERN "*.h" PATTERN "*.hpp" PATTERN "*.inl")
if (RENDERIVE_BUILD_TESTS)
    set(Renderive_Kernel_test_dir "${CMAKE_CURRENT_LIST_DIR}/tests")
    append_glob_source(Renderive_Kernel_test_sources "${Renderive_Kernel_test_dir}")
    foreach (Renderive_Kernel_test_source IN LISTS Renderive_Kernel_test_sources)
        if (NOT Renderive_Kernel_test_source MATCHES "\\.(c|cc|cpp|cxx)$")
            continue()
        endif ()
        file(RELATIVE_PATH Renderive_Kernel_test_name "${Renderive_Kernel_test_dir}" "${Renderive_Kernel_test_source}")
        string(REGEX REPLACE "\\.[^.]+$" "" Renderive_Kernel_test_name "${Renderive_Kernel_test_name}")
        string(MAKE_C_IDENTIFIER "${Renderive_Kernel_test_name}" Renderive_Kernel_test_name)
        set(Renderive_Kernel_test_target "Renderive_Kernel_${Renderive_Kernel_test_name}")
        add_executable("${Renderive_Kernel_test_target}" "${Renderive_Kernel_test_source}")
        target_include_directories("${Renderive_Kernel_test_target}" PRIVATE
                "${Renderive_Kernel_test_dir}"
                "${CMAKE_CURRENT_LIST_DIR}/../render_2D"
                "${CMAKE_CURRENT_LIST_DIR}/../render_3D"
        )
        target_link_libraries("${Renderive_Kernel_test_target}" PRIVATE Renderive_Kernel GTest::gtest_main)
        renderive_stage_kernel_runtime("${Renderive_Kernel_test_target}")
        add_test(NAME "${Renderive_Kernel_test_target}" COMMAND "${Renderive_Kernel_test_target}")
        set_tests_properties("${Renderive_Kernel_test_target}" PROPERTIES LABELS "Renderive_Kernel")
        list(APPEND Renderive_Kernel_test_targets "${Renderive_Kernel_test_target}")
    endforeach ()
    add_custom_target(Renderive_Kernel_check
            COMMAND "${CMAKE_CTEST_COMMAND}" --test-dir "${CMAKE_BINARY_DIR}"
            -C "$<CONFIG>" -L "^Renderive_Kernel$" --output-on-failure
            DEPENDS ${Renderive_Kernel_test_targets}
            USES_TERMINAL)
endif ()