set(Renderive_render_2D_dependencies global::blend2d)
if (RENDERIVE_BUILD_TESTS)
    set(Renderive_render_2D_test_targets)
    list(APPEND Renderive_render_2D_dependencies global::GTest)
endif ()
rcl_add_dependency_action_targets(Renderive_render_2D_env ${Renderive_render_2D_dependencies})
set_target_properties(Renderive_render_2D_env PROPERTIES FOLDER Renderive_render_2D)
library_get_missing_with_rely(Renderive_render_2D_dependencies_missing ${Renderive_render_2D_dependencies})
if (Renderive_render_2D_dependencies_missing)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_render_2D dependencies\n${Renderive_render_2D_dependencies_missing}\n are not installed. Build Renderive_render_2D_env first")
    return()
endif ()
rcl_load_dependency_environment(${Renderive_render_2D_dependencies})
find_package(blend2d CONFIG REQUIRED)
if (RENDERIVE_BUILD_TESTS)
    find_package(GTest CONFIG REQUIRED)
endif ()
if (NOT TARGET Renderive_Kernel)
    rcl_log_append(${CMAKE_CURRENT_LIST_LINE} "[FATAL_ERROR] Renderive_render_2D requires Renderive_Kernel")
    return()
endif ()
set(Renderive_render_2D_source_dir "${CMAKE_CURRENT_LIST_DIR}/render_2D")
append_glob_source(Renderive_render_2D_sources "${Renderive_render_2D_source_dir}")
add_library(Renderive_render_2D STATIC ${Renderive_render_2D_sources})
add_library(Renderive::Render2D ALIAS Renderive_render_2D)
set_target_properties(Renderive_render_2D PROPERTIES EXPORT_NAME Render2D)
target_include_directories(Renderive_render_2D PUBLIC
        "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}>"
        "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
)
target_compile_features(Renderive_render_2D PUBLIC cxx_std_20)
target_link_libraries(Renderive_render_2D PUBLIC
        Renderive_Kernel
        blend2d::blend2d)
if (MSVC)
    target_compile_options(Renderive_render_2D PRIVATE /utf-8)
endif ()
install(TARGETS Renderive_render_2D
        EXPORT RenderiveTargets
        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
        RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
install(DIRECTORY "${Renderive_render_2D_source_dir}/"
        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/render_2D"
        FILES_MATCHING PATTERN "*.h" PATTERN "*.hpp")
if (RENDERIVE_BUILD_TESTS)
    set(Renderive_render_2D_test_dir "${CMAKE_CURRENT_LIST_DIR}/tests")
    append_glob_source(Renderive_render_2D_test_sources "${Renderive_render_2D_test_dir}")
    foreach (Renderive_render_2D_test_source IN LISTS Renderive_render_2D_test_sources)
        if (NOT Renderive_render_2D_test_source MATCHES "\\.(c|cc|cpp|cxx)$")
            continue()
        endif ()
        file(RELATIVE_PATH Renderive_render_2D_test_name "${Renderive_render_2D_test_dir}" "${Renderive_render_2D_test_source}")
        string(REGEX REPLACE "\\.[^.]+$" "" Renderive_render_2D_test_name "${Renderive_render_2D_test_name}")
        string(MAKE_C_IDENTIFIER "${Renderive_render_2D_test_name}" Renderive_render_2D_test_name)
        set(Renderive_render_2D_test_target "Renderive_render_2D_${Renderive_render_2D_test_name}")
        add_executable("${Renderive_render_2D_test_target}" "${Renderive_render_2D_test_source}")
        target_link_libraries("${Renderive_render_2D_test_target}" PRIVATE Renderive_render_2D GTest::gtest_main)
        renderive_stage_kernel_runtime("${Renderive_render_2D_test_target}")
        add_test(NAME "${Renderive_render_2D_test_target}" COMMAND "${Renderive_render_2D_test_target}")
        set_tests_properties("${Renderive_render_2D_test_target}" PROPERTIES
                LABELS "Renderive_render_2D"
                ENVIRONMENT "RENDERIVE_ERROR_MODE=exception")
        list(APPEND Renderive_render_2D_test_targets "${Renderive_render_2D_test_target}")
    endforeach ()
    add_custom_target(Renderive_render_2D_check
            COMMAND "${CMAKE_CTEST_COMMAND}" --test-dir "${CMAKE_BINARY_DIR}"
                    -C "$<CONFIG>" -L "^Renderive_render_2D$" --output-on-failure
            DEPENDS ${Renderive_render_2D_test_targets}
            USES_TERMINAL)
endif ()